xprot termcrc
startserver "term -x\r"
stopserver "^C^W\rexit\r"

setvar today cdate(time())
setvar datelog right(today,2)+left(today,2)+midstr(today,4,2)

logfile $(datelog).log overwrite
log "Beginning transfers."

for system in (*.nfo) do
   setvar sysname left(system,len(system)-4)
   fopen 1,system,'R'
      freadln 1,username
      freadln 1,pass
      freadln 1,sendfile
      freadln 1,getfile
   fclose 1

   user username
   password pass
   login "^L06^T10^Slogin:^S^W^U^SPassword:^S^W^P"
   if !exist($(sysname).con)
      log sysname;" connection file does not exist."

    else
      iferror connect $(sysname).con
         log "Can't connect to ";sysname;"."
         log "Skipping to next system."

       else
         login
         dwait "\$"
         startserver
         dwait "OK"

          iferror xfer $(sendfile) $(sendfile)
             log "Couldn't send $(sendfile) to $(sysname)."
          endif

          iferror get $(getfile)
             log "Couldn't get $(getfile) from $(sysname)."
          endif

         stopserver

      endif
   endif
endfor

log "Transfers completed."
logfile close

quit
